launchergame/build.gradle

buildscript {
	repositories {
		jcenter()
	}
	dependencies {
		classpath 'com.github.jengelman.gradle.plugins:shadow:2.0.2'
	}
}

plugins {
	id 'com.github.johnrengelman.shadow' version '2.0.2'
	id 'org.hidetake.ssh' version '2.9.0'
	id 'application'
	id 'java'
	id 'idea'
}

mainClassName = 'com.projectswg.launcher.game.GameLauncher'
sourceCompatibility = 1.8
targetCompatibility = 1.8

sourceSets {
	main {
		java {
			srcDir 'src'
		}
	}
}

shadowJar {
	baseName = "GameLauncher"
	classifier = null
	version = null
}

dependencies {
	compile project(':PSWGCommon')
	compile project(':ClientHolocore')
	compile project(':Forwarder')
	
	compile group: "me.joshlarson", name: "fast-json", version: "2.2.3"
}

repositories {
	jcenter()
}

task wrapper(type: Wrapper) {
	gradleVersion = "4.4"
}

remotes {
	server {
		host = 'patch1.projectswg.com'
		user = 'root'
		identity = file("${System.properties['user.home']}/.ssh/id_rsa_pswg_patch")
	}
}

task deploy(dependsOn: shadowJar) {
	doLast {
		ssh.run {
			session(remotes.server) {
				put from: shadowJar.archivePath, into: '/var/www/patch1.projectswg.com/launcher_patch/GameLauncher.jar'
			}
		}
	}
}