Holocore/build.gradle

import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar

buildscript {
	repositories {
		jcenter()
	}
	dependencies {
		classpath 'com.github.jengelman.gradle.plugins:shadow:2.0.4'
	}
}

plugins {
	id 'application'
	id 'java'
	id 'idea'
}

mainClassName = 'com.projectswg.holocore.ProjectSWG'
sourceCompatibility = 10
targetCompatibility = 10

apply plugin: 'com.github.johnrengelman.shadow'

sourceSets {
	display { }
	utility { }
}

test {
	testLogging {
		events "skipped", "failed" // just good to know in terms of what failed
	}
	afterSuite { TestDescriptor td, TestResult tr ->
		if (td.parent == null) {
			println 'Tests run: (' + tr.getTestCount() + '), Failures: (' + tr.getFailedTestCount() + ')' // IMPORTANT - this is required for Lightspeed
		}
	}
	include 'com/projectswg/holocore/TestAll.class' // to run only a single test case
}

shadowJar {
	baseName = "Holocore"
	classifier = null
	version = null
}

repositories {
	jcenter()
}

dependencies {
	compile project(':pswgcommon')
	
	compile group: 'org.xerial', name: 'sqlite-jdbc', version: '3.23.1'
	compile group: 'org.mongodb', name: 'mongo-java-driver', version: '3.6.3'
	
	testCompile 'junit:junit:4.12'
	
	displayCompile project(':pswgcommon')
	displayCompile sourceSets.main.output
	
	utilityCompile project(':pswgcommon')
	utilityCompile sourceSets.main.output
	utilityCompile group: 'org.xerial', name: 'sqlite-jdbc', version: '3.23.1'
	utilityCompile group: 'org.mongodb', name: 'mongo-java-driver', version: '3.6.3'
}

task CreateConvertLoginJar(type: ShadowJar) {
	archiveName = 'ConvertLogin.jar'
	manifest.attributes 'Main-Class': 'com.projectswg.utility.ConvertLogin'
	from sourceSets.utility.output
	configurations = [project.configurations.utilityRuntime]
	exclude('META-INF/INDEX.LIST', 'META-INF/*.SF', 'META-INF/*.DSA', 'META-INF/*.RSA')
}